home *** CD-ROM | disk | FTP | other *** search
/ Linear Technology Linearview 1996 / linearview 1996.iso / spice / lt1221 < prev    next >
Encoding:
Text File  |  1996-07-09  |  4.1 KB  |  130 lines
  1. * 
  2. * Linear Technology LT1221 op amp model  
  3. * Written: 2-01-1993 10:25:47 Type: Bipolar NPN input, internal comp.
  4. * Modified by G.F. to add Cload compensation network and freq. shaping
  5. * Typical specs: 
  6. * Vos=3.0E-04, Ib=1.0E-07, Ios=1.0E-07, GBP=150E+06Hz, Phase mar.= 60 deg Av=4, 
  7. * SR(-)=250V/us, SR(+)=250V/us, Av= 100dB, CMRR=114dB, 
  8. * Vsat(+)=2.00V, Vsat(-)=2.50V, Isc=+40/-40mA, Rout=50ohms, Iq=8.00mA.
  9. * 
  10. * Connections: + - V+V-O 
  11. .SUBCKT LT1221 3 2 7 4 6 
  12. * INPUT
  13. RC1 7  80 1E+03
  14. RC2 7  90 1E+03
  15. Q1  80 2  10 QM1 
  16. Q2  90 3  11 QM2 
  17. CIN 2  3  2.0000E-12
  18. C1  80 90 0.265E-12
  19. *INPUT POLE AT 300MHZ
  20. RE1 10 12 218
  21. RE2 11 12 218
  22. *    RE1, RE2 REDUCED VS LT1220 TO REFLECT HIGHER GM
  23. IEE 12 4  1E-03
  24. RE  12 0  2.3E+05
  25. CE  12 0  2E-12
  26. *CE ADDED TO GIVE ASSYMETRICAL SLEW FOR NON-INVERTING GAINS
  27. * INTERMEDIATE
  28. *MODS: GA DEPENDENCE INVERTED (POLARITY SWAPPED)
  29. *      R2 INCREASED TO 30MOHM (ALL GAIN IN ONE STAGE)
  30. *      C2 TIED TO GROUND (WAS NODE 1), REDUCED TO 3.11PF FROM 3.54PF 
  31. *      GB POLARITY REVERSED, GB=1/R02 FOR GAIN OF 1 
  32. *      RF, CF ADDED FOR CLOAD NETWORK (REDUCES VALUE OF C2)
  33. *      REVERSE POLARITY OF GNL,GPL,GCL,GCM FOR LIMITING BECAUSE OF GA REVERSAL
  34. *      ADD MULTIPLE POLES AND A ZERO BETWEEN GA STAGE AND GB STAGE
  35. GCM 8  0  12 0  7.2E-09
  36. GA  8  0  90 80 1.0E-3
  37. R2  8  0  28.4E+06
  38. C2  8  0  3.51E-12
  39. *POLE AT 180MHZ
  40. GX1 0  28 8  0  1E-06
  41. RX1 28 0  1E+06
  42. CX1 28 0  0.885E-15
  43. *POLE AT 180MHZ
  44. GX2 0  38 28 0  1E-06
  45. RX2 38 0  1E+06
  46. CX2 38 0  0.885E-15
  47. *POLE AT 180MHZ
  48. GX3 0  48 38 0  1E-06
  49. RX3 48 0  1E+06
  50. CX3 48 0  0.885E-15  
  51. *ZERO AT 60MHZ
  52. GX4 0  58 48 0  1E-06
  53. RX4 58 59 1E+06
  54. LX4 59 0  2.65E-03
  55. *POLE AT 360MHZ
  56. GX5 0  68 58 0  1E-06
  57. RX5 68 0 1E+06
  58. CX5 68 0 .443E-15
  59. *POLE AT 360MHZ
  60. GX6 0  78 68 0  1E-06
  61. RX6 78 0  1E+06
  62. CX6 78 0  .443E-15
  63. *
  64. GB  0  1  78 0  20.4E-03
  65. RO2 1  0  49
  66. RF  8  99 3200
  67. CF  99 6  5E-12
  68. * OUTPUT 
  69. RSO 1  6  1.0000E+00
  70. ECL 18 0  1  6  2.3987E+01
  71. GCL 8  0  20 0  1.0000E+00
  72. RCL 20 0  1.0000E+01
  73. D1  18 19 DM1  
  74. VOD1 19 20 5.9605E-08
  75. D2  20 21 DM1  
  76. VOD2 21 18 5.9605E-08
  77. * 
  78. D3A 131 70 DM3 
  79. D3B 13 131 DM3 
  80. GPL 8  0  70 7  1.0000E+00
  81. VC  13 6  3.4909E+00
  82. RPLA 7  70 1.0000E+01
  83. RPLB 7  131 1.0000E+03
  84. D4A 60 141 DM3 
  85. D4B 141 14  DM3 
  86. GNL 8  0  60 4  1.0000E+00
  87. VE  6  14 3.9909E+00
  88. RNLA 60 4  1.0000E+01
  89. RNLB 141 4  1.0000E+03
  90. * 
  91. IP  7  4  7E-03
  92. DSUB 4  7  DM2  
  93. * MODELS 
  94. .MODEL QM1 NPN (IS=8.0E-16 BF=10E+03)
  95. .MODEL QM2 NPN (IS=8.1E-16 BF=3.33E+03)
  96. .MODEL DM1  D   (IS=1.0000E-20)
  97. .MODEL DM2  D   (IS=8.0000E-16 BV=4.3200E+01)
  98. .MODEL DM3  D   (IS=1.0000E-16)
  99. .ENDS LT1221
  100. * 
  101. * - - - - - * fini LT1221 * - - - - - *
  102. ***
  103. *         (C) COPYRIGHT LINEAR TECHNOLOGY CORPORATION 1993
  104. *                       All rights reserved.
  105. * 
  106. *   Linear Technology Corporation hereby grants the users of this
  107. * macromodel a non-exclusive, nontransferrable license to use this
  108. *            macromodel under the following conditions:
  109. * 
  110. * The user agrees that this macromodel is licensed from Linear
  111. * Technology and agrees that the macromodel may be used, loaned,
  112. * given away or included in other model libraries as long as this
  113. * notice and the model in its entirety and unchanged is included.
  114. * No right to make derivative works or modifications to the
  115. * macromodel is granted hereby.  All such rights are reserved.
  116. * 
  117. * This model is provided as is.  Linear Technology makes no
  118. * warranty, either expressed or implied about the suitability or
  119. * fitness of this model for any particular purpose.  In no event
  120. * will Linear Technology be liable for special, collateral,
  121. * incidental or consequential damages in connection with or arising
  122. * out of the use of this macromodel.  It should be remembered that
  123. * models are a simplification of the actual circuit.
  124. * 
  125. * Linear Technology reserves the right to change these macromodels
  126. * without prior notice.  Contact Linear Technology at 1630 McCarthy
  127. * Blvd., Milpitas, CA, 95035-7487 or telephone 408/432-1900 for
  128. * datasheets on the actual amplifiers or the latest macromodels.
  129. * 
  130. * ----------------------------------------------------------------------- *